제2의 비엔지니어 인생관을 꿈꾸며

Posted
Filed under Study

Get-Cluster -Name HVCLUSTER.domain.local | select ClusterFunctionalLevel

Windows server 2012 R2 에서는 레벨이 8입니다. Windows Server 2016 및 Hyper-V Server 2016 Core 를 설치하고 나서 2012 R2 클러스터 그룹에 가입이 되지만 가입되는 동시에 클러스터 관리도구가 2012 R2에서는 버젼문제로 접근할수 없게됩니다. 그러면 2016이나 Windows 10 RSAT로 클러스터관리도구를 사용해야되며  기존 2012 R2 노드들은 드레이닝으로 각 가상화 컴퓨터들을 다른노드로 이전하고 노드삭제하고 2016 설치하고 재가입 시키는 수순으로 진행하면 별무리가 없습니다.
전부 2016으로 설치가 완료되고 클러스터 그룹에 가입이 완료되면 클러스터 레벨을 업그레이드 시켜줍니다.

Get-Cluster -Name HVCLUSTER.domain.local | update-ClusterFunctionalLevel
레벨수준이 8에서 9로 업그레이드가 완료됩니다.

사용자 삽입 이미지

업그레이드가 완료되면 2012에서 보이지 않던 클러스터 인프라 리소스가 추가된것을 확인할수가 있습니다.



2017/01/09 09:23 2017/01/09 09:23
Posted
Filed under Study


https://blogs.technet.microsoft.com/askpfeplat/2012/12/09/why-adding-hyper-v-replica-connection-broker-fails-in-failover-cluster-manager/
사용자 삽입 이미지

MSCS 환경에서 복제본 브로커 등록할때 실패가 떨어지는 경우가 간혹 있습니다.
사용자 삽입 이미지

수동으로 복제본 브로커 컴퓨터 개체를 만들고 속성에 보안탭에 MSCS 클러스터 컴퓨터 개체를 등록해주고 풀권한을 주고 확인을 주면 해결이 됩니다.
사용자 삽입 이미지
이방법은 복제본 브로커 등록 실패뿐만이 아니고 MSSQL 사전설치 DTC 구성시에도 등록실패가 발생하는 경우도 간혹 있습니다. 이와 같은 방법으로 클러스터 컴퓨터 개체의 권한을 등록시켜줘서 자동으로 업데이트 되게 하는 방법이 있습니다.
위에 링크에는 두번째 방법  특정권한을 위임해주는 방법도 존재합니다만 전 첫번째 옵션 방법이 단번에 해결되어서 두번째 방법까지 쓸 경우가 없었습니다.
2017/01/08 04:02 2017/01/08 04:02
Posted
Filed under Study
USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
  DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
    @binvalue varbinary(256),
    @hexvalue varchar (514) OUTPUT
AS
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
  DECLARE @tempint int
  DECLARE @firstint int
  DECLARE @secondint int
  SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
  SELECT @firstint = FLOOR(@tempint/16)
  SELECT @secondint = @tempint - (@firstint*16)
  SELECT @charvalue = @charvalue +
    SUBSTRING(@hexstring, @firstint+1, 1) +
    SUBSTRING(@hexstring, @secondint+1, 1)
  SELECT @i = @i + 1
END

SELECT @hexvalue = @charvalue
GO

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
  DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @type varchar (1)
DECLARE @hasaccess int
DECLARE @denylogin int
DECLARE @is_disabled int
DECLARE @PWD_varbinary  varbinary (256)
DECLARE @PWD_string  varchar (514)
DECLARE @SID_varbinary varbinary (85)
DECLARE @SID_string varchar (514)
DECLARE @tmpstr  varchar (1024)
DECLARE @is_policy_checked varchar (3)
DECLARE @is_expiration_checked varchar (3)

DECLARE @defaultdb sysname

IF (@login_name IS NULL)
  DECLARE login_curs CURSOR FOR

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'
ELSE
  DECLARE login_curs CURSOR FOR


      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs

FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
  PRINT 'No login(s) found.'
  CLOSE login_curs
  DEALLOCATE login_curs
  RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status <> -1)
BEGIN
  IF (@@fetch_status <> -2)
  BEGIN
    PRINT ''
    SET @tmpstr = '-- Login: ' + @name
    PRINT @tmpstr
    IF (@type IN ( 'G', 'U'))
    BEGIN -- NT authenticated account/group

      SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
    END
    ELSE BEGIN -- SQL Server authentication
        -- obtain password and sid
            SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
        EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
        EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT

        -- obtain password policy state
        SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
        SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name

            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'

        IF ( @is_policy_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
        END
        IF ( @is_expiration_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
        END
    END
    IF (@denylogin = 1)
    BEGIN -- login is denied access
      SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
    END
    ELSE IF (@hasaccess = 0)
    BEGIN -- login exists but does not have access
      SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
    END
    IF (@is_disabled = 1)
    BEGIN -- login is disabled
      SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
    END
    PRINT @tmpstr
  END

  FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
   END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO

다음단계 master db 에서 쿼리창 열고
EXEC sp_help_revlogin
을 실행시키면 각계정마다 아래와 같이 출력이 됩니다.
CREATE LOGIN [Test] WITH PASSWORD = '', SID = 0x90FD605DCEFAE14FAB4D5EB0BBA1AECC, DEFAULT_DATABASE = [master], CHECK_POLICY = ON, CHECK_EXPIRATION = OFF

필자가 해본결과로는 조금 틀리게 나오는데 MSSQL버젼때문인지는 몰라도
-- Login: testuser
CREATE LOGIN [testuser] WITH PASSWORD = 0x020022FB4795F3FE36F30074E97A9F2C8A37775119EEDF6E29AF05D3B8E2C7959EB7190
D8DF8A57826541AF213ACAFB1B0BEE4A475568D4DFE5DA626C1451D6D09B08F9E3E8F HASHED, SID = 0x2086C2394C37AE4D9A175731783AFE77, DEFAULT_DATABASE = [testDB], CHECK_POLICY = OFF, CHECK_EXPIRATION = OFF
암호해쉬 와 정책 및 만료체크를 사용안함으로 추가가 되었습니다. 아마도 기본값이 암호 및 정책이 되어 있으면 복원하자마자 잠김상태가 되는거기때문에 이렇게 다르게 나오나봅니다.

2016/12/27 16:20 2016/12/27 16:20